I’m trying to simulate a 6-pin device where 2 pins are NC according to the model file (pins 3 and 5).
The KiCAD symbol has those pins as Unconnected, which I hope is correct.
But in the Pin Assignment window in the schematic simulator setup it’s impossible to assign two Not Connected pins. Either only one is allowed, or KiCAD insists that NC has to be assigned. But that’s not possible to two pins. I’m at my wit’s end.
How to proceed?
I attach pro, sch, wks, model and screenshot. Scratch2.kicad_pro (13.4 KB) Scratch2.kicad_sch (17.5 KB) Scratch2_1.wbk (1.6 KB) BRT22H.lib (2.5 KB)
You may set one node to ‘unconnected’, the other to ‘NC’.
If successful, however, you then have to un-check current and power measurement for transient simulation, as otherwise then there is another Eeschema/ngspice bug when two or more unconnected nodes are there. eeschema may send ‘unconnected’ nodes to ngspice which have the same name, ngspice then fails. I have corrected this in ngspice (available in ngspice-44). Better to fix this in Eeschema.
The download zip has numerous changes.
It includes the following modified SPICE that will parse in simulation.
Includes the symbol which has all pins visible and is assignable to a DIP6.
I just added a pcb with the BRT22 DIP 6 footprint and 3D model to the zip file.
==========
* NC PINS REPLACED WITH 3 & 5 CONNECT TO 0 (GND)
* Library of Phototriac Optocoupler BRT22H
* Copyright VISHAY, Inc. 2018 All Rights Reserved.
*
.SUBCKT BRT22H A C 3 MT2 5 MT1
X1 MT2 GATE MT1 BRT22H_tr
D1 10 C Demit
V3 11 10 0Vdc
R3 A 11 1u TC=0,0
R4 0 3 1MEG
C1 0 5 1u
G1 0 20 VALUE { If( abs(v(MT2) - v(MT1)) <= 5, I(v3)*2.6, 0 ) }
C2 0 20 10u
V4 20 21 0Vdc
R5 21 0 1
G_G2 0 GATE VALUE { i(V4) }
.MODEL Demit d
+IS=1e-15 RS=0.852101 N=1.51873 EG=1.3
+XTI=4 BV=6.04 IBV=5e-6 CJO=1e-11
+VJ=0.7 M=0.5 FC=0.5 TT=1e-09
+KF=0 AF=1
.ENDS
**********
.SUBCKT BRT22H_tr 1 2 3
* TERMINALS: MT2 G MT1
QN1 5 4 3 NOUT OFF
QN2 11 6 7 NOUT OFF
QP1 6 11 3 POUT OFF
QP2 4 5 7 POUT OFF
DF 4 5 DZ
DR 6 11 DZ
RF 4 6 60000.00Meg
RT2 1 7 8.00
RH 7 6 3.75k
RGP 8 3 102
RG 2 8 998
RS 8 4 3.65k
DN 9 2 DIN
RN 9 3 855
GNN 6 7 9 3 24.3u
GNP 4 5 9 3 26.5u
DP 2 10 DIP
RP 10 3 110k
GP 7 6 10 3 20.5u
.MODEL DIP D ( IS=1.07f N=1.50 )
.MODEL DIN D ( IS=1.07f)
.MODEL DZ D ( IS=1.07f N=1.5 IBV=100u BV=600 )
.MODEL POUT PNP ( IS=1.07f BF=5 BR=.1 CJE=335f TF=0.850u )
.MODEL NOUT NPN ( IS=1.07f BF=20 BR=.1 CJE=335f CJC=67.0f TF=0.0510u )
.ENDS
**************
**===================================================================
* Note:
* Although models can be a useful tool in evaluating device performance,
* they cannot model exact device performance under all conditions, nor
* are they intended to replace breadboarding for final verification.
* Models provided by VISHAY Semiconductors GmbH (“Vishay”) do not represent
* all of the specifications and operating characteristics of the product to
* which the model relates. The models attempt to describe the characteristics
* of typical products. The current data sheet information for a given
* product represents the final design guideline and includes actual
* performance specifications. The accuracy, reliability and compatibility
* of models provided by Vishay are not guaranteed or warranted in any way
* and Vishay disclaims liability of any kind whatsoever, including, without
* limitation, liability for quality, performance, merchantability and fitness
* for a particular purpose arising out of the use, or inability to use a model.
* Vishay reserves the right to change models without prior notice.
* The products described herein, including the model and any results produced
* using the model, are subject to the specific disclaimers set forth at www.vishay.com/doc?91000.
**===================================================================
==========
