AC motors simulation (1 phase & 3 phase)

Have anybody an idea how to simulate AC motors?
Thanks, Josef

I am guessing these are AC induction motors. The Apollo 13 mission was in progress, and the SPICE simulator wasn’t even available yet, when I last sat in a class on electrical machinery. But I seem to recall that the model for an induction motor looks a lot like the model for a transformer. If you can’t find anything helpful in the messages and archives of the LTSpice User Group , seed a search engine with “spice motor simulation” or “spice motor models”.


For AC, and Power supply you may find this NL5 simulator is much easy, fast, and helpfull. Or you can use AC simulation mode from ngspice to do it.

In both case, you need to make a simple model of your motor using ideal transformer, inductance, resistor, capacitor…

I had use both to simulate power regulator circuits with transformer. If you need a boost with KiCad, I guest you can try ngspice files that I posted in this forum.

Good luck :slight_smile:

FYI: You can event use idea circuit part to simulators heat transferring, motor loads etc - if you model it correctly.

Here spice AC motor model (3 phase) for KiCAD Im1
net liste:
.title KiCad schematic
.include “ADZ.lib”
V2 0 Net-V2-Pad2 sin(0 220 50 0 0 -120)
V1 0 Net-V1-Pad2 sin(0 220 50 0 0 0)
V3 0 Net-V3-Pad2 sin(0 220 50 0 0 120)
X1 Net-V1-Pad2 Net-V2-Pad2 Net-V3-Pad2 w m 0 ADZ
R1 w 0 1.57
R2 m 0 1meg
.tran 0.1m 3 uic

spice-library AC motor (file ADZ.lib):

.subckt ADZ a b c ww mm z
.param Zp=2 Lm=0.0287 Ls=0.0294 Lr=0.0297 Rs=0.067 Rr=0.032 Cj=0.64
R1 a N001 {Rs}
R2 b N003 {Rs}
R3 c N005 {Rs}
L1 N001 nn {Ls}
L2 N003 nn {Ls}
L3 N005 nn {Ls}
L4 N002 N004 {1.5* Lr }
R5 N004 z {1.5* Rr }
B10 N002 z V=-{Zp}* v(ww)* ({Lm}* sqrt(3.)/2.* (i(L2)-i(L3)) + 1.5* {Lr}* i(L5))
L5 N006 N007 {1.5 * Lr}
R6 N007 z {1.5 * Rr }
B11 N006 z V={Zp}* v(ww) * ( 3.0/2.0 * {Lm} * i(L1) + 1.5 * {Lr} * i(L4) )
k1 L1 L4 {Lm/sqrt(Ls * 1.5* Lr )}
k2 L2 L4 {-Lm/(2. * sqrt(Ls * 1.5 * Lr))}
k3 L2 L5 {sqrt(3.) * Lm/(2.* sqrt(Ls * 1.5 * Lr))}
k4 L3 L4 {-Lm/(2. * sqrt(Ls * 1.5 * Lr ))}
k5 L3 L5 {-sqrt(3.) * Lm/(2. * sqrt(Ls * 1.5 * Lr ))}
B9 z ww I={Zp} * sqrt(3.)/2 * {Lm} * ( (i(L2)-i(L3)) * i(L4) - sqrt(3.) * i(L1) * i(L5))
Cw z ww {Cj}
B12 z mm V=-I(B9)
.ends ADZ

Here the general theory of construction of model is placed (in french):
"Algorithmes pour la formation des équations de la machine électrique généralisée sous forme tensorielle "